home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do / MODEM.PROG.bas < prev    next >
BASIC Source File  |  1996-12-24  |  3KB  |  50 lines
  1. 10  GOTO 250: REM  ALL ""'S=CTRL-G
  2. 20  HOME :F = 0: DIM N$(23),NUM$(23)
  3. 30 Q$ =  CHR$(17):D$ =  CHR$(4)
  4. 40 A$ = "ABCDEFGHIJKLMNOPQRSTUV"
  5. 50 X = 1: REM  GET READY TO READ DATA
  6. 60  READ N$(X),NUM$(X): IF N$(X) = "END"  THEN F = 1: GOTO 90
  7. 70  PRINT  MID$ (A$,X,1)". ";N$(X);: HTAB 29: PRINT NUM$(X)
  8. 80 X = X +1: IF X <23  THEN 60
  9. 90  PRINT : PRINT "WHOM DO YOU WISH TO CALL:";: GET I$
  10. 100  IF I$ > CHR$(64)  AND I$ < CHR$(86)  THEN 130
  11. 110  IF I$ =  CHR$(27)  OR I$ =  CHR$(32)  THEN 130
  12. 120  FLASH : HTAB 26: PRINT "TRY AGAIN";"<CTRL-G>": NORMAL : FOR X = 1 TO 1000: NEXT X: RESTORE :F = 0: HOME : GOTO 50
  13. 130  IF I$ =  CHR$(27)  THEN  GOTO 250
  14. 140  IF I$ =  CHR$(32)  AND F < >1  THEN  HOME : GOTO 50
  15. 150  IF I$ =  CHR$(32)  THEN  HOME : RESTORE :F = 0: GOTO 50
  16. 160 X =  ASC(I$) -64
  17. 165  IF N$(X) = "END"  OR N$(X) = ""  THEN 120
  18. 170  HOME : VTAB 10: HTAB 16: FLASH : PRINT "CALLING": NORMAL : PRINT : HTAB 19 - LEN(N$(X))/2: PRINT N$(X)
  19. 180  PRINT D$;"PR#2": PRINT Q$;NUM$(X); CHR$(10)
  20. 190  VTAB 10: HTAB 16: PRINT "       ": VTAB 16: HTAB 13: FLASH : PRINT "PICK UP PHONE": NORMAL 
  21. 200  PRINT "<CTRL-G>": PRINT "<CTRL-G>": PRINT "<CTRL-G>"
  22. 210  FOR X = 1 TO 6000: NEXT X
  23. 220  PRINT D$;"PR#2": PRINT  CHR$(26)
  24. 230  FOR X = 1 TO 3000: NEXT X
  25. 240  RESTORE :F = 0: HOME : GOTO 50
  26. 250  HOME : VTAB 3: PRINT : PRINT "1. YOU MUST HAVE A D.C.HAYES MICROMODEM": PRINT "II INSTALLED IN SLOT 2 TO USE THIS": PRINT "PROGRAM."
  27. 255  PRINT : PRINT "2. TO CALL A NUMBER PRESS THE LETTER OF": PRINT "THE PERSON OR COMPANY THAT YOU": PRINT "WISH TO CALL."
  28. 260  PRINT : PRINT "3. THE SPACE BAR IS USED TO FLIP PAGES": PRINT "IF YOU HAVE MORE THAN ONE PAGE OF ": PRINT "NUMBERS."
  29. 270  PRINT : PRINT "4. THE <ESC> KEY IS USED TO GET TO AND": PRINT "FROM THIS PAGE."
  30. 280  PRINT : PRINT "5. ADD ADDITIONAL NAMES AND PHONE": PRINT "NUMBERS AS DATA STATEMENTS AT THE END": PRINT "OF THE PROGRAM BUT INSURE THE LAST DATA": PRINT "STATEMENT IS <END,999>."
  31. 290  GET I$: IF I$ < > CHR$(27)  THEN 290
  32. 300  IF T = 0  THEN T = 1: GOTO 20
  33. 310  RESTORE :F = 0: HOME : GOTO 50
  34. 320  DATA  APPLE ADV.ALLIANCE,13076328561
  35. 330  DATA  APPLE COMPUTER CO.,14089961010
  36. 340  DATA  D.C.HAYES,14044498791
  37. 350  DATA  STOWERS GEORGE,12078827824
  38. 360  DATA  MICRO CO-OP,13122321777
  39. 370  DATA  MUSE,13016597212
  40. 380  DATA  SENSIBLE SOFTWARE,13133998877
  41. 390  DATA  SUBLOGIC,12173598482
  42. 400  DATA  THE SOURCE,18003363366
  43. 9998  DATA  TEST,YOUR NUMBER
  44. 9999  DATA  END,999
  45. 10000  REM     AUTO DIALER
  46. 10001  REM         BY
  47. 10002  REM  GEORGE N. STOWERS
  48. 10003  REM  BOX 1910 RD#2
  49. 10004  REM  WISCASSET,ME. 04578
  50. 10005  REM  TEL.(207) 882-7824